Tech » MD5
MD5 implementation for Lotus Script
This an implementation of RFC1321 (The MD5 Message-Digest Algorithm) for the Lotus Notes environment.
Translations: Belorussian by Bohdan Zograf.
Usage
- Save and unzip the code to a text file (libMD5_R5.lss)
- Use Domino Designer to create a new empty Lotus Script library 'libMD5'
- import libMD5_R5.lss and save the lib
- Now you can include the library (Use "libMD5") and call DigestStrToHex (...) for example.
Download
Download libMD5_R5.zip (4kB)
This Version uses the Integer instead if Byte
type and was tested on R5.
Download libMD5_R6.zip (4kB)
This Version uses the Byte type and requires Domino 6
or higher to run.
This lib also contains a function DigestFileToHexStr().
Releated links
Change Log and previous releases
2005-11-13 |
v1.1 |
|
2003-09-27 |
v1.0 |
First release |
Code
(The following code is a modified version of the Visual
Basic implementation by Robert Hubley and David Midkiff)
Option Public
Option Declare
%REM
libMD5_R6 v1.1
Standard MD5 implementation optimised for the Lotus Notes environment.
Conforms to all standards and can be used in digital signature or password
protection related schemes. (--> http://www.faqs.org/rfcs/rfc1321.html )
Based on the Visual Basic MD5 Implementation by Robert Hubley and David Midkiff
This version uses the 'Byte' type, which is available on R6 only.
There is also a version available that uses Integer instead so it runs on R5.
(Current source: http://wwWendt.de/tech/md5 )
Martin Wendt (martin(at)wwWendt.de)
[2005-11-13 mw]: v1.1
- modified MD5Update() and MD5Final() to fix padding bug that produced wrong
checksums when (Length Mod 64) = 56
- modified DigestFileToHexStr() to fix a bug when (Length mod 64) = 0
- added some test cases
[2003-09-27 mw]: v1.0
- created this file
--------------------------------------------------------------------------------
Usage:
Get hash value for a string:
hash = DigestStrToHexStr (strIn)
Get hash value for a text file:
hash = DigestFileToHexStr (filePath)
Incremental update:
Dim aByte () As Byte, chunk As String
Call MD5Init()
[...]
loop
chunk = ...
Call MD5StringToArray (chunk, aByte)
Call MD5Update (Len(chunk), aByte)
end loop
Call MD5Final()
hash = MD5GetValues()
%END REM
Private Const OFFSET_4 = 4294967296#
Private Const MAXINT_4 = 2147483647
Private State(4) As Long
Private ByteCounter As Long
' [mw]: needed this wrapper to make file Get() work
'Private ByteBuffer(63) As Byte
Type TByteBufferWrapper
bb(63) As Byte
End Type
Private ByteBuffer As TByteBufferWrapper
Private Const S11 = 7
Private Const S12 = 12
Private Const S13 = 17
Private Const S14 = 22
Private Const S21 = 5
Private Const S22 = 9
Private Const S23 = 14
Private Const S24 = 20
Private Const S31 = 4
Private Const S32 = 11
Private Const S33 = 16
Private Const S34 = 23
Private Const S41 = 6
Private Const S42 = 10
Private Const S43 = 15
Private Const S44 = 21
Private Property Get RegisterA() As String
RegisterA = State(1)
End Property
Private Property Get RegisterB() As String
RegisterB = State(2)
End Property
Private Property Get RegisterC() As String
RegisterC = State(3)
End Property
Private Property Get RegisterD() As String
RegisterD = State(4)
End Property
Private Function LongToString(Num As Long) As String
Dim A As Byte, B As Byte, C As Byte, D As Byte
A = Num And &HFF&
If A < 16 Then LongToString = "0" & Hex(A) Else LongToString = Hex(A)
B = (Num And &HFF00&) \ 256
If B < 16 Then LongToString = LongToString & "0" & Hex(B) Else LongToString = LongToString & Hex(B)
C = (Num And &HFF0000) \ 65536
If C < 16 Then LongToString = LongToString & "0" & Hex(C) Else LongToString = LongToString & Hex(C)
If Num < 0 Then D = ((Num And &H7F000000) \ 16777216) Or &H80& Else D = (Num And &HFF000000) \ 16777216
If D < 16 Then LongToString = LongToString & "0" & Hex(D) Else LongToString = LongToString & Hex(D)
End Function
Private Sub MD5Transform(Buffer() As Byte)
Dim X(16) As Long, A As Long, B As Long, C As Long, D As Long
A = State(1)
B = State(2)
C = State(3)
D = State(4)
Decode 64, X, Buffer
FF A, B, C, D, X(0), S11, -680876936
FF D, A, B, C, X(1), S12, -389564586
FF C, D, A, B, X(2), S13, 606105819
FF B, C, D, A, X(3), S14, -1044525330
FF A, B, C, D, X(4), S11, -176418897
FF D, A, B, C, X(5), S12, 1200080426
FF C, D, A, B, X(6), S13, -1473231341
FF B, C, D, A, X(7), S14, -45705983
FF A, B, C, D, X(8), S11, 1770035416
FF D, A, B, C, X(9), S12, -1958414417
FF C, D, A, B, X(10), S13, -42063
FF B, C, D, A, X(11), S14, -1990404162
FF A, B, C, D, X(12), S11, 1804603682
FF D, A, B, C, X(13), S12, -40341101
FF C, D, A, B, X(14), S13, -1502002290
FF B, C, D, A, X(15), S14, 1236535329
GG A, B, C, D, X(1), S21, -165796510
GG D, A, B, C, X(6), S22, -1069501632
GG C, D, A, B, X(11), S23, 643717713
GG B, C, D, A, X(0), S24, -373897302
GG A, B, C, D, X(5), S21, -701558691
GG D, A, B, C, X(10), S22, 38016083
GG C, D, A, B, X(15), S23, -660478335
GG B, C, D, A, X(4), S24, -405537848
GG A, B, C, D, X(9), S21, 568446438
GG D, A, B, C, X(14), S22, -1019803690
GG C, D, A, B, X(3), S23, -187363961
GG B, C, D, A, X(8), S24, 1163531501
GG A, B, C, D, X(13), S21, -1444681467
GG D, A, B, C, X(2), S22, -51403784
GG C, D, A, B, X(7), S23, 1735328473
GG B, C, D, A, X(12), S24, -1926607734
HH A, B, C, D, X(5), S31, -378558
HH D, A, B, C, X(8), S32, -2022574463
HH C, D, A, B, X(11), S33, 1839030562
HH B, C, D, A, X(14), S34, -35309556
HH A, B, C, D, X(1), S31, -1530992060
HH D, A, B, C, X(4), S32, 1272893353
HH C, D, A, B, X(7), S33, -155497632
HH B, C, D, A, X(10), S34, -1094730640
HH A, B, C, D, X(13), S31, 681279174
HH D, A, B, C, X(0), S32, -358537222
HH C, D, A, B, X(3), S33, -722521979
HH B, C, D, A, X(6), S34, 76029189
HH A, B, C, D, X(9), S31, -640364487
HH D, A, B, C, X(12), S32, -421815835
HH C, D, A, B, X(15), S33, 530742520
HH B, C, D, A, X(2), S34, -995338651
II A, B, C, D, X(0), S41, -198630844
II D, A, B, C, X(7), S42, 1126891415
II C, D, A, B, X(14), S43, -1416354905
II B, C, D, A, X(5), S44, -57434055
II A, B, C, D, X(12), S41, 1700485571
II D, A, B, C, X(3), S42, -1894986606
II C, D, A, B, X(10), S43, -1051523
II B, C, D, A, X(1), S44, -2054922799
II A, B, C, D, X(8), S41, 1873313359
II D, A, B, C, X(15), S42, -30611744
II C, D, A, B, X(6), S43, -1560198380
II B, C, D, A, X(13), S44, 1309151649
II A, B, C, D, X(4), S41, -145523070
II D, A, B, C, X(11), S42, -1120210379
II C, D, A, B, X(2), S43, 718787259
II B, C, D, A, X(9), S44, -343485551
State(1) = LongOverflowAdd(State(1), A)
State(2) = LongOverflowAdd(State(2), B)
State(3) = LongOverflowAdd(State(3), C)
State(4) = LongOverflowAdd(State(4), D)
End Sub
Private Sub Decode(Length As Integer, OutputBuffer() As Long, InputBuffer() As Byte)
Dim intDblIndex As Integer, intByteIndex As Integer, dblSum As Double
For intByteIndex = 0 To Length - 1 Step 4
dblSum = InputBuffer(intByteIndex) + InputBuffer(intByteIndex + 1) * 256# _
+ InputBuffer(intByteIndex + 2) * 65536# + InputBuffer(intByteIndex + 3) * 16777216#
OutputBuffer(intDblIndex) = UnsignedToLong(dblSum)
intDblIndex = intDblIndex + 1
Next intByteIndex
End Sub
Private Function FF(A As Long, B As Long, C As Long, D As Long, X As Long, S As Long, ac As Long) As Long
A = LongOverflowAdd4(A, (B And C) Or (Not (B) And D), X, ac)
A = LongLeftRotate(A, S)
A = LongOverflowAdd(A, B)
End Function
Private Function GG(A As Long, B As Long, C As Long, D As Long, X As Long, S As Long, ac As Long) As Long
A = LongOverflowAdd4(A, (B And D) Or (C And Not (D)), X, ac)
A = LongLeftRotate(A, S)
A = LongOverflowAdd(A, B)
End Function
Private Function HH(A As Long, B As Long, C As Long, D As Long, X As Long, S As Long, ac As Long) As Long
A = LongOverflowAdd4(A, B Xor C Xor D, X, ac)
A = LongLeftRotate(A, S)
A = LongOverflowAdd(A, B)
End Function
Private Function II(A As Long, B As Long, C As Long, D As Long, X As Long, S As Long, ac As Long) As Long
A = LongOverflowAdd4(A, C Xor (B Or Not (D)), X, ac)
A = LongLeftRotate(A, S)
A = LongOverflowAdd(A, B)
End Function
Private Function LongLeftRotate(value As Long, Bits As Long) As Long
Dim lngSign As Long, lngI As Long
Bits = Bits Mod 32
If Bits = 0 Then LongLeftRotate = value: Exit Function
For lngI = 1 To Bits
lngSign = value And &HC0000000
value = (value And &H3FFFFFFF) * 2
' value = value Or ((lngSign < 0) And 1) Or (Cbool(lngSign And &H40000000) And &H80000000)
value = value Or ((lngSign < 0) And 1) Or (False<>(lngSign And &H40000000) And &H80000000)
Next
LongLeftRotate = value
End Function
Private Function LongOverflowAdd(Val1 As Long, Val2 As Long) As Long
Dim lngHighWord As Long, lngLowWord As Long, lngOverflow As Long
lngLowWord = (Val1 And &HFFFF&) + (Val2 And &HFFFF&)
lngOverflow = lngLowWord \ 65536
lngHighWord = (((Val1 And &HFFFF0000) \ 65536) + ((Val2 And &HFFFF0000) \ 65536) + lngOverflow) And &HFFFF&
LongOverflowAdd = UnsignedToLong((lngHighWord * 65536#) + (lngLowWord And &HFFFF&))
End Function
Private Function LongOverflowAdd4(Val1 As Long, Val2 As Long, val3 As Long, val4 As Long) As Long
Dim lngHighWord As Long, lngLowWord As Long, lngOverflow As Long
lngLowWord = (Val1 And &HFFFF&) + (Val2 And &HFFFF&) + (val3 And &HFFFF&) + (val4 And &HFFFF&)
lngOverflow = lngLowWord \ 65536
lngHighWord = (((Val1 And &HFFFF0000) \ 65536) + ((Val2 And &HFFFF0000) \ 65536) _
+ ((val3 And &HFFFF0000) \ 65536) + ((val4 And &HFFFF0000) \ 65536) + lngOverflow) And &HFFFF&
LongOverflowAdd4 = UnsignedToLong((lngHighWord * 65536#) + (lngLowWord And &HFFFF&))
End Function
Private Function UnsignedToLong(value As Double) As Long
If value < 0 Or value >= OFFSET_4 Then Error 6
If value <= MAXINT_4 Then UnsignedToLong = value Else UnsignedToLong = value - OFFSET_4
End Function
Private Function LongToUnsigned(value As Long) As Double
If value < 0 Then LongToUnsigned = value + OFFSET_4 Else LongToUnsigned = value
End Function
Sub md5StringToArray (InString As String, aByte () As Byte)
Dim n As Long, i As Long
n = Len (InString)
Redim aByte (n) ' one byte too much, but n may be 0
For i = 0 To n - 1
aByte(i) = Asc(Mid$(InString, i + 1, 1))
Next i
End Sub
Public Sub MD5Init()
ByteCounter = 0
State(1) = UnsignedToLong(1732584193#)
State(2) = UnsignedToLong(4023233417#)
State(3) = UnsignedToLong(2562383102#)
State(4) = UnsignedToLong(271733878#)
End Sub
Public Sub MD5Update(InputLen As Long, InputBuffer() As Byte)
If InputLen=0 Then Exit Sub
Dim nBufferedBytes As Integer, nBufferRemaining As Integer
Dim iInputBuffer As Long, i As Long
nBufferedBytes = ByteCounter Mod 64
nBufferRemaining = 64 - nBufferedBytes
If InputLen >= nBufferRemaining Then
' use up old buffer results first
If nBufferedBytes>0 Then
For iInputBuffer = 0 To nBufferRemaining-1
ByteBuffer.bb(nBufferedBytes + iInputBuffer) = InputBuffer(iInputBuffer)
Next
Call MD5Transform (ByteBuffer.bb)
End If
' transform remaining complete 64 byte chunks
Dim nChunks As Long, iChunk As Long
nChunks = (InputLen - iInputBuffer) \ 64 ' Integer Division
For iChunk = 1 To nChunks
For i = 0 To 63
ByteBuffer.bb(i) = InputBuffer (iInputBuffer + i)
Next
Call MD5Transform (ByteBuffer.bb)
iInputBuffer = iInputBuffer + 64
Next
' append remaining input bytes to buffer
For i = 0 To InputLen-iInputBuffer-1
ByteBuffer.bb(i) = InputBuffer (iInputBuffer+i)
Next
Else
' append input to buffer
For i = 0 To InputLen-1
ByteBuffer.bb(nBufferedBytes+i) = InputBuffer (i)
Next
End If
ByteCounter = ByteCounter + InputLen
End Sub
Public Sub MD5Final()
Dim dblBits As Double, padding(72) As Byte, nBytesBuffered As Long, nBufferRemaining As Integer
padding(0) = &H80 ' rest is zeroed
dblBits = ByteCounter * 8
nBytesBuffered = ByteCounter Mod 64
nBufferRemaining = 64 - nBytesBuffered
If nBufferRemaining >= 9 Then
' enough space for at least one padding byte and 8 size bytes
Call MD5Update (nBufferRemaining - 8, padding)
Else
' not enough space in current buffer: make 2 buffers
Call MD5Update (64 + nBufferRemaining - 8, padding)
End If
padding(0) = UnsignedToLong(dblBits) And &HFF&
padding(1) = UnsignedToLong(dblBits) \ 256 And &HFF&
padding(2) = UnsignedToLong(dblBits) \ 65536 And &HFF&
padding(3) = UnsignedToLong(dblBits) \ 16777216 And &HFF&
padding(4) = 0
padding(5) = 0
padding(6) = 0
padding(7) = 0
Call MD5Update (8, padding)
%REM
Dim dblBits As Double, padding(72) As Byte, lngBytesBuffered As Long
padding(0) = &H80
dblBits = ByteCounter * 8
lngBytesBuffered = ByteCounter Mod 64
If lngBytesBuffered <= 56 Then MD5Update 56 - lngBytesBuffered, padding Else MD5Update 120 - ByteCounter, padding
padding(0) = UnsignedToLong(dblBits) And &HFF&
padding(1) = UnsignedToLong(dblBits) \ 256 And &HFF&
padding(2) = UnsignedToLong(dblBits) \ 65536 And &HFF&
padding(3) = UnsignedToLong(dblBits) \ 16777216 And &HFF&
padding(4) = 0
padding(5) = 0
padding(6) = 0
padding(7) = 0
MD5Update 8, padding
%END REM
End Sub
Public Function DigestStrToHexStr(SourceString As String) As String
MD5Init
Dim aByte () As Byte
Call MD5StringToArray (SourceString, aByte)
MD5Update Len(SourceString), aByte
MD5Final
DigestStrToHexStr = MD5GetValues
End Function
Public Function DigestFileToHexStr(fspec As String) As String
%REM
Calculate md5 for a file.
Note: this code is pretty slow, so don't use it for big files
( about 15 kB/s on a P4 @ 2 GHz)
%END REM
On Error Goto CATCH
Const bShowProcess = False
' Ignore 'input past end of file' error
On Error 62 Resume Next
Dim hFile As Integer
hFile = Freefile
Open fspec For Binary Access Read As #hFile
MD5Init
Do While Not Eof(hFile)
Get #hFile, , ByteBuffer
If ( Loc(hFile) Mod 64 ) = 0 Then ' got a full 64 byte block?
ByteCounter = ByteCounter + 64
MD5Transform ByteBuffer.bb
End If
If bShowProcess Then
Dim nBlocks As Long
nBlocks = nBlocks + 1
If nBlocks Mod 160 = 0 Then '
Print ByteCounter & " bytes..."
End If
End If
Loop
' process remaing bytes
ByteCounter = ByteCounter + (Loc(hFile) Mod 64)
MD5Final
Close #hFile
DigestFileToHexStr = MD5GetValues
Exit Function
CATCH:
DigestFileToHexStr = ""
Exit Function
End Function
Public Function MD5GetValues() As String
MD5GetValues = LongToString(State(1)) & LongToString(State(2)) _
& LongToString(State(3)) & LongToString(State(4))
End Function
Private Function md5Test0 (strIn As String, strHash As String, bDump As Integer) As Integer
Dim res As String, msg As String
res = DigestStrToHexStr(strIn)
msg = "MD5('" & strIn & "') = '" & res & "'"
If Strcompare(res,strHash,1)=0 Then
msg = msg & " [ok]"
md5Test0 = True
Else
msg = msg & " --> ERROR! Should be '" & strHash & "'"
md5Test0 = False
End If
If bDump Then Print msg
End Function
Function md5Test (bDump As Integer) As Integer
' MD5 test suite (http://www.faqs.org/rfcs/rfc1321.html)
' Print "CBool:" & Clng(true=Cbool (1))
Dim bRes As Integer
bRes = True
bRes = bRes And md5Test0 ("", "d41d8cd98f00b204e9800998ecf8427e", bDump)
bRes = bRes And md5Test0 ("a", "0cc175b9c0f1b6a831c399e269772661", bDump)
bRes = bRes And md5Test0 ("abc", "900150983cd24fb0d6963f7d28e17f72", bDump)
bRes = bRes And md5Test0 ("message digest", "f96b697d7cb7938d525a2f31aaf161d0", bDump)
bRes = bRes And md5Test0 ("abcdefghijklmnopqrstuvwxyz", "c3fcd3d76192e4007dfb496cca67e13b", bDump)
bRes = bRes And md5Test0 ("ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789",
"d174ab98d277d9f5a5611c2c9f419d9f", bDump)
bRes = bRes And md5Test0 ("12345678901234567890123456789012345678901234567890123456789012345678901234567890",
"57edf4a22be3c955ac49da2e2107b67a", bDump)
' some additional tests at /around 64 byte block boundaries:
bRes = bRes And md5Test0 (String$(63, "a"), "b06521f39153d618550606be297466d5", bDump)
bRes = bRes And md5Test0 (String$(64, "a"), "014842d480b571495a4a0363793f7367", bDump)
bRes = bRes And md5Test0 (String$(65, "a"), "c743a45e0d2e6a95cb859adae0248435", bDump)
' some additional tests at/around (Len mod 64) = 56 to find padding bugs:
bRes = bRes And md5Test0 (String$(55, "a"), "ef1772b6dff9a122358552954ad0df65", bDump)
bRes = bRes And md5Test0 (String$(56, "a"), "3b0c8ac703f828b04c6c197006d17218", bDump)
bRes = bRes And md5Test0 (String$(57, "a"), "652b906d60af96844ebd21b674f35e93", bDump)
bRes = bRes And md5Test0 (String$(119, "a"), "8a7bd0732ed6a28ce75f6dabc90e1613", bDump)
bRes = bRes And md5Test0 (String$(120, "a"), "5f61c0ccad4cac44c75ff505e1f1e537", bDump)
bRes = bRes And md5Test0 (String$(121, "a"), "f6acfca2d47c87f2b14ca038234d3614", bDump)
md5Test = bRes
If bRes Then
Print "Test Passed!"
Else
Print "Test FAILED!"
End If
End Function